if,正如它E文中的意思，就是“如果”的意思，用来进行条件判断。翻译过来的意思就是：如果符合某一条件，便执行后面的命令。
主要用来判断，1、两个“字符串”是否相等；2、两个数值是大于、小于、等于,然后执行相应的命令。
当然还有特殊用法，如结合errorlevel：if errorlevel 1 echo error
或者结合defined（定义的意思）:if defined test (echo It is defined) else echo It isn't defined
用法示例：
1、检测字符串(注意，用if检测字符串是否相等的时候，后面用的不是“=”，而是“==”)
代码:
@echo off
set "str=this is a test"
REM 检测变量%str%是否等于test，如果相等，显示OK，否则显示NO
if "%str%"=="test" (echo OK) else echo NO
pause>nul
2、检测数值：（注意，批处理中大于符号不能用：“>”,而用"gtr"，其它的也类似）
比较运算符一览：
EQU - 等于
NEQ - 不等于
LSS - 小于
LEQ - 小于或等于
GTR - 大于
GEQ - 大于或等于
检测数值 20 是否大于 15演示代码：
@echo off
set /a num1=20
set /a num2=15
if %num1% gtr %num2% echo %num1%大于%num2%
if %num1% EQU %num2% echo %num1%等于%num2%
if %num1% LSS %num2% echo %num1%小于%num2%
pause>nul
3、if结合errorlevel使用：
说明：环境变量errorlevel的初始值为0，当一些命令执行不成功，就会返回一个数值，如：1 ，2 等
IF-ERRORLEVEL
测试代码：
@ECHO OFF
XCOPY F:\test.bat D:\
IF ERRORLEVEL 1 ECHO 文件拷贝失败
IF ERRORLEVEL 0 ECHO 成功拷贝文件
如果文件拷贝成功，屏幕就会显示“成功拷贝文件”，否则就会显示“文件拷贝失败”。
IF ERRORLEVEL 是用来测试它的上一个DOS命令的返回值的，注意只是上一个命令的返回值，而且返回值必须依照从大到小次序顺序判断。
因此下面的批处理文件是错误的：
@ECHO OFF
XCOPY C:\AUTOEXEC.BAT D:\
IF ERRORLEVEL 0 ECHO 成功拷贝文件
IF ERRORLEVEL 1 ECHO 未找到拷贝文件
IF ERRORLEVEL 2 ECHO 用户通过ctrl-c中止拷贝操作
IF ERRORLEVEL 3 ECHO 预置错误阻止文件拷贝操作
IF ERRORLEVEL 4 ECHO 拷贝过程中写盘错误
无论拷贝是否成功，后面的：
未找到拷贝文件
用户通过ctrl-c中止拷贝操作
预置错误阻止文件拷贝操作
拷贝过程中写盘错误
都将显示出来。
附录：
以下就是几个常用命令的返回值及其代表的意义：
backup
0 备份成功
1 未找到备份文件
2 文件共享冲突阻止备份完成
3 用户用ctrl-c中止备份
4 由于致命的错误使备份操作中止
diskcomp
0 盘比较相同
1 盘比较不同
2 用户通过ctrl-c中止比较操作
3 由于致命的错误使比较操作中止
4 预置错误中止比较
diskcopy
0 盘拷贝操作成功
1 非致命盘读/写错
2 用户通过ctrl-c结束拷贝操作
3 因致命的处理错误使盘拷贝中止
4 预置错误阻止拷贝操作
format
0 格式化成功
3 用户通过ctrl-c中止格式化处理
4 因致命的处理错误使格式化中止
5 在提示“proceed with format（y/n）?”下用户键入n结束
xcopy
0 成功拷贝文件
1 未找到拷贝文件
2 用户通过ctrl-c中止拷贝操作
4 预置错误阻止文件拷贝操作
5 拷贝过程中写盘错误
4、if还有一个特殊的用法就是可以用来检测某个变量是否已经被定义
用法示例：
@echo off
set "str1=ok"
set "str2=no"
if defined str1 echo str1已经被定义
if defined str2 echo str2已经被定义
if defined str3 (echo str3已经被定义) else echo str3 没有被定义
pause>nul
5:变量名 本身无所谓大小写，但是内容有区别
测试：
命令行下：if "F"=="f" echo ok
忽略大小写请在if后加开关/i
示例：if /i "F"=="f" echo ok
6:if exist 文件（目录） 命令
意思是如果存在文件或目录，就执行后面的命令，如果不存在则跳转。
示例1：
@echo off
if not exist e:\aaa goto nofile
rd /q "e:\aaa"
pause
exit
:nofile
md e:\aaa© E:\test\123.txt e:\aaa
pause
以上意思表示：如果E盘存在“aaa”文件夹，则执行下一条命令(rd /q "e:\aaa")，如果不存在文件夹“aaa”则跳转(goto nofile)到“:nofile”标签处，执行后面的命令(md e:\aaa© E:\test\123.txt e:\aaa)
注意：如果要查看的文件夹是带点的，则用短文件名的形式，如“if not exist e:\aaa..\”应写成“if not exist e:\aaa~1"的形式。
示例2：
if exist E:\aaa\* del /q E:\aaa\*
pause
示例3：
if exist %windir%\explorer.exe dir /x /a %windir%\*.exe
pause
标签：批处理,翻译
